Background

For display purposes, I sometimes find it desirable to defeat Mathematica's canonical ordering of variables, and instead have it output terms in the order in which I type them. E.g., instead of this:

b-a
v=v0+a t
a8+a9+a10

–a + b

a t + v0

a10 + a8 + a9

...I'd prefer this:

b – a

v0 + a t

a8 + a9 + a10

This can be easily accomplished by removing the Orderless attributes from Plus and Times, entering the expression, and then immediately restoring those attributes, but I don't know of a way to implement this series of commands as a function:

ClearAttributes[Plus, Orderless]
ClearAttributes[Times, Orderless]
e1=c (b-a)
SetAttributes[Plus, Orderless]
SetAttributes[Times, Orderless]
e2=c (b-a) (*confirm that Orderless is restored to both Plus and Times*)
e1==e2 (*check that functionality isn't affected by how function is displayed; want output to be "True"*)

c (b – a)

(–a + b) c

True

Question

How do I define a function such that:

e1=func[c (b-a)]
e2=c (b-a) (
e1==e2 

c (b – a)

(–a + b) c

True

Notes:
(1) I want to alter only the display format, not any other functionality. E.g., MMA should still recognize that e1 and e2 are mathematically equivalent, even though e1 was defined while the Orderless Attribute was absent from both Plus and Times.

(2) This is not quite a duplicate of Changing the display ordering of orderless functions? because there the OP was looking for a function that would dictate the display order, while I was looking for a simpler approach that merely displayed the output in the same order that I typed it. [So the function would just act to protect the display order, rather than specify it.]

(3)This was originally a question that ended up having two separate parts.
To make the information in this more readily searchable, I've divided this question into two (this being the first part). See: Dividing one thread into two

You could define a format that does this for you:

SetAttributes[orderlessForm, HoldFirst]

MakeBoxes[orderlessForm[expr_], form_] ^:= Internal`InheritedBlock[Times, Plus,
 ClearAttributes[Times, Plus, Orderless];
 MakeBoxes[expr, form]
]

Then:

orderlessForm[c (b - a)]

c (b - a)

And, the usual output when not using the wrapper:

c (b - a)

(-a + b) c

Note that the HoldFirst attribute does most of the work.

I decided to contact Wolfram Technical Support (WTS) on this one. Working together, we were able to find a construction that meets my needs:

SetAttributes[fun1, HoldAll]
fun1[expr_] := Module[, Print[Style[HoldForm[expr], 13]]; expr];
e1 = fun1[c*(b - a)];
e2 = c*(b - a)
e1 == e2

c (b-a)

(-a + b) c

True

The HoldAll statement is necessary because, without it, MMA would sort the function's argument into canonical order before HoldForm is applied:

fun2[expr_] := Module[, Print[Style[HoldForm[expr], 13]]; expr];
e1 = fun2[c*(b - a)];

(-a+b) c

A comment by Mr. Wizard (see below) indicates this can also be accomplished using a pure function:

fun3 = Function[expr, Print[Style[HoldForm[expr], 13]]; expr, HoldAll];
e1 = fun3[c*(b - a)];
e2 = c*(b - a)
e1 == e2

c (b-a)

(-a + b) c

True