mjhjmtu

I have %var1% and %var2%

var1="UserInput"
var2=file.log

If a user types %var1% as "file.txt", how can I (if possible) check only the three last characters (Or the file format if that's possible) to see if it matches %var2%'s three last characters or file format?

Another method that does the same thing is also welcome (But the user-input variable must be there)

How do I check if the three last characters of a variable match another variable?

Use variable substring syntax to extract the last 3 characters of each variable.

Example batch file:

@echo off
setlocal
set /p var1="UserInput: "
set var1last3=%var1:~-3%
set var2=file.log
set var2last3=%var2:~-3%
if %var1last3% == %var2last3% (
 echo Match
 ) else (
 echo No Match
 )
endlocal

Further Reading

• An A-Z Index of the Windows CMD command line | SS64.com


• Windows CMD Commands (categorized) - Windows CMD - SS64.com


• If - Conditionally perform command - Windows CMD - SS64.com


• Set - Environment Variable - Windows CMD - SS64.com


• variable substring - Windows CMD - SS64.com

If you are going to check a fixed number of characters, then you should check the last 4, else "file.Log" will match "file.myLog".

But the best option is to get the actual extension, regardless the length:

@echo off
setlocal
set "var1=file.Log"
set "var2=file.myLog"

:: Option 1 using FOR loops
for %%A in ("%var1%") do for %%B in ("%var2%") do if "%%~xA"=="%%~xB" (
 echo Match
) else (
 echo No Match
)

: Option 2 using CALL parameters
call :matchExtension "%var1%" "%var2%" &&echo Match||echo No Match
exit /b

:matchExtension file1 fil2 --> returns 0 (success) if match, 1 (error) if no match
if "%~x1"=="%~x2" exit /b 0
exit /b 1