mjhjmtu

This expression is taken from a talk given by the late Robby Villegas. The UpValues to some symbol a is defined below as:

ClearAll["a"];
a /: _[___, a, ___] := (Print["a fired"]; Null)

Nothing I tried could Clear the definitions associated with the symbol. Is there a way to clear the associated UpValues.

Note that you could clear all of the *Values by using Clear["a"] or ClearAll["a"]. However, if you only want to clear this particular UpValues you could make use of the fact that HoldAllComplete prevents UpValues from firing. So, temporarily give TagUnset this attribute. Here's your UpValues definition:

ClearAll["a"];
a /: _[___,a,___] := (Print["a fired"];Null)

Give TagUnset the HoldAllComplete attribute, and unset the above definition:

Internal`InheritedBlock[TagUnset,
 SetAttributes[TagUnset, HoldAllComplete];
 TagUnset[a, _[___,a,___]]
]

Check:

UpValues[a]

a /: Except[TagUnset, _][___, a, ___] := (Print["a fired"]; Null);

f[a]
(* a fired *)

(* As we can see below, usage of ClearAll does not work *)

ClearAll[a]
(* a fired *)


(* now removing the associated values using the TagUnset Head *)

TagUnset[Unevaluated[a],HoldPattern[Except[TagUnset, _][___, a, ___]]];

f[a]
(* f[a] *)